home *** CD-ROM | disk | FTP | other *** search
/ Software Vault: The Gold Collection / Software Vault - The Gold Collection (American Databankers) (1993).ISO / cdr26 / dos60sup.zip / DBLBOOT.BA_ / DBLBOOT.bin
Text File  |  1993-04-05  |  2KB  |  75 lines
  1. @echo off
  2. rem Batch file to create a bootable, DoubleSpaced floppy.
  3.  
  4. if "%1" == "sub" goto sub
  5. if "%1" == "/?" goto usage
  6. if not "%1" == "" goto start
  7.  
  8. :usage
  9. echo.
  10. echo Batch file to create a bootable, DoubleSpaced floppy. For use only with 
  11. echo high density (1.44 and 1.2 megabyte) diskettes. Lower density diskettes when
  12. echo DoubleSpaced do not have adequate uncompressed space for system files 
  13. echo required for booting.
  14. echo.
  15. echo Usage:  dblboot drive
  16. echo.
  17. goto end
  18.  
  19. :start
  20. echo.
  21. echo This batch file will create a bootable DoubleSpaced diskette on either
  22. echo a 1.44 megabyte 3.5 inch or 1.2 megabyte 5.25 inch floppy. Lower density
  23. echo DoubleSpaced diskettes do not have adequate uncompressed space for system
  24. echo files and should not be used.
  25. choice /c:yn "Do you wish to continue"
  26. if errorlevel 2 goto end
  27.  
  28. if "%1" == "a:" goto diskette
  29. if "%1" == "b:" goto diskette
  30. echo You have selected drive %1
  31. choice /c:yn "Is this correct"
  32. if errorlevel 2 goto end
  33.  
  34. :diskette
  35. choice /c:ny "Is diskette already compressed"
  36. if errorlevel 2 goto nocompress
  37. choice /c:yn "Do you wish to format the diskette first"
  38. if errorlevel 2 goto noformat
  39.  
  40. format %1 /u
  41. :noformat
  42. dblspace /compress %1 
  43. :nocompress
  44. rem If we can see the CVF on the specified drive it isn't mounted.
  45. if exist %1\dblspace.000 dblspace /mount %1
  46. dblspace /size /reserve=.2 %1
  47. copy c:\command.com %1\
  48. dblspace /unmount %1
  49. deltree /y %1\dblspace.ini
  50. sys %1
  51. set srcdir=.
  52. for %%d in (%path%) do call %0 sub %%d
  53. if not exist %srcdir%\dblboot.ini goto notfound
  54. copy %srcdir%\dblboot.ini %1\dblspace.ini
  55. set srcdir=
  56. attrib %1\dblspace.ini +s +h +r
  57.  
  58. choice /c:yn "Mount new compressed drive now"
  59. if errorlevel 2 goto end
  60. dblspace /mount %1
  61. goto end
  62.  
  63. :sub
  64. if exist %2\dblboot.ini set srcdir=%2
  65. goto end
  66.  
  67. :notfound
  68. echo Prototype ini file (dblboot.ini) not found.
  69. echo Make sure it is in current directory or in the path.
  70.  
  71. :end
  72.  
  73.  
  74.  
  75.